Sabeis como podría cambiar el color del encabezado de un 
formulario mediante código? Quiero hacer que dependa de 
un checkbox, si está en blanco o en No naranja si está en 
SI en verde... a que evento debería asociar el código al 
Update, al Load...?


EDUARDO OLAZ
============

Supongamos que tienes un formulario con un encabezado de nombre
EncabezadoDelFormulario
Supongamos que tienes un CheckBox de nombre chkValor
Puedes hacer un procedimiento [AjustarColorEncabezado] que te consulte el
valor del CheckBox y ajuste el color del encabezado en función del valor del
mismo.
A ese procedimiento tienes que llamarlo desde el evento [Al activar
registro] (Current) del formulario, y desde el evento [Después de
actualizar] (AfterUpdate) del CheckBox.
Según el tipo de dato que tengas asociado al CheckBox, éste puede contener
un valor Null, por lo que lo paso antes por la función Nz
     If Nz(chkValor, 0) Then
            .  .  .  .

Esto te puede servir
________________________________

' Colores para el fondo del encabezado
' RGB(0, 255, 0) --> 65280 = vbGreen
Const conclrVerde As Long = vbGreen
' RGB(255, 128, 0) --> 33023
Const conclrNaranja As Long = 33023

Private Sub Form_Current()
    AjustarColorEncabezado
End Sub

Private Sub chkValor_AfterUpdate()
    AjustarColorEncabezado
End Sub

Private Sub AjustarColorEncabezado()
    If Nz(chkValor, 0) Then
        EncabezadoDelFormulario.BackColor = conclrVerde
    Else
        EncabezadoDelFormulario.BackColor = conclrNaranja
    End If
End Sub
________________________________