Sub CreateTableDefX()

   Dim dbsNorthwind As Database
   Dim tdfNew As TableDef
   Dim prpLoop As Property

   Set dbsNorthwind = OpenDatabase("Northwind.mdb")

   ' Create a new TableDef object.
   Set tdfNew = dbsNorthwind.CreateTableDef("Contacts")

   With tdfNew
      ' Create fields and append them to the new TableDef 
      ' object. This must be done before appending the 
      ' TableDef object to the TableDefs collection of the 
      ' Northwind database.
      .Fields.Append .CreateField("FirstName", dbText)
      .Fields.Append .CreateField("LastName", dbText)
      .Fields.Append .CreateField("Phone", dbText)
      .Fields.Append .CreateField("Notes", dbMemo)

      Debug.Print "Properties of new TableDef object " & _
         "before appending to collection:"

      ' Enumerate Properties collection of new TableDef 
      ' object.
      For Each prpLoop In .Properties
         On Error Resume Next
         If prpLoop <> "" Then Debug.Print "  " & _
           prpLoop.Name & " = " & prpLoop
         On Error GoTo 0
      Next prpLoop

      ' Append the new TableDef object to the Northwind 
      ' database.
      dbsNorthwind.TableDefs.Append tdfNew

      Debug.Print "Properties of new TableDef object " & _
         "after appending to collection:"

      ' Enumerate Properties collection of new TableDef 
      ' object.
      For Each prpLoop In .Properties
         On Error Resume Next
         If prpLoop <> "" Then Debug.Print "  " & _
           prpLoop.Name & " = " & prpLoop
         On Error GoTo 0
      Next prpLoop

   End With

   ' Delete new TableDef object since this is a 
   ' demonstration.
   dbsNorthwind.TableDefs.Delete "Contacts"

   dbsNorthwind.Close

End Sub

Con DDL
Sub crear_tblClientes()
Dim cadSQL As String

    cadSQL = "CREATE TABLE tblClientes " _
    & "(IdCliente COUNTER PRIMARY KEY," _
    & "[Nombre] TEXT(25) NOT NULL, " _
    & "[Apellidos] TEXT(50) NOT NULL, " _
    & "Direccion TEXT(100), " _
    & "Poblacion TEXT(50), " _
    & "CodPostal TEXT(5), " _
    & "Pais TEXT(50), " _
    & "Telefono TEXT(20), " _
    & "Email TEXT(50))"

    CurrentDb.Execute cadSQL
    'CurrentProject.Connection.Execute cadSQL

End Sub

si utilizas Acc2000 o superior, en vez de la linea

    CurrentDb.Execute

puedes utilizar CurrentProject.Connection.Execute ...

ya que para trabajar con este tipo de instrucciones tiene más posibilidades.