Me gustaría deshabilitar el comando cerrar y el cuadro de control cuando
utilizo una base de datos. Cómo puedo hacerlo?

Juan M. Afan de Ribera
======================

 Para desactivar el comando cerrar de la base de datos utiliza esta línea
de código:

     CommandBars("Menu Bar"). _
     Controls("Archivo"). _
     Controls("Salir").Enabled = False

y para desactivar los botones y el menú de la ventana de Access utiliza
este código (ponlo en un módulo estandar y llama a la función

 DesactivarBotonesAccess):

 Private Declare Function GetSystemMenu _
       Lib "user32" _
       (ByVal hwnd As Long, _
       ByVal bRevert As Long) As Long

 Private Declare Function GetMenuItemCount _
       Lib "user32" _
       (ByVal hMenu As Long) As Long

 Private Declare Function DrawMenuBar _
       Lib "user32" _
       (ByVal hwnd As Long) As Long

 Private Declare Function RemoveMenu _
       Lib "user32" _
       (ByVal hMenu As Long, _
       ByVal nPosition As Long, _
       ByVal wFlags As Long) As Long

 Const MF_BYPOSITION = &H400&
 Const MF_REMOVE = &H1000&

 Public Sub DesactivarBotonesAccess()
    Dim WinWnd As Long
    Dim i As Integer

    WinWnd = Application.hWndAccessApp

    Dim hSysMenu As Long, nCnt As Long
    hSysMenu = GetSystemMenu(WinWnd, False)

    If hSysMenu Then
       nCnt = GetMenuItemCount(hSysMenu)
       If nCnt Then
          For i = nCnt - 1 To 0 Step -1
             RemoveMenu hSysMenu, i, MF_BYPOSITION Or MF_REMOVE
             DrawMenuBar Application.hWndAccessApp
          Next
       End If
    End If

 End Sub