Tengo una serie de consultas... y quiero exportar el resultado de c/u a un mismo archivo
de excel pero en distintas hojas... es decir, necesito la sintaxis que me
permita indicar el archivo de excel y la hoja en la que quiero colocar esos datos

JUAN M AFAN DE RIBERA
=====================

Primero de todo, deberás ir a la ventana del editor de Visual Basic y añade
una referencia a la Microsoft Excel version_que_tengas Object Library y a la
Microsoft DAO x.x Object Library. Después, en un módulo estandar copia y
pega este procedimiento que exportará a Excel las tablas o consultas que le
pongas como parámetros y lo colocará todo en un mismo libro. Lo puedes
llamar de esta manera:

ExportarExcel "Consulta1","Consulta2","Consulta3","Tabla1" '(todas las consultas o tablas que necesites)

Sub ExportarExcel(ParamArray nombresQueries() As Variant)
Dim appExcel As New Excel.Application
Dim hoja As Object
Dim rst As Recordset
Dim fld As Field
Dim i As Integer
Dim nom As String
Dim fila As Integer, columna As Integer

    'abrimos excel y añadimos un libro nuevo
    appExcel.Visible = True
    appExcel.Workbooks.Add

    For i = 0 To UBound(nombresQueries())

        'añadimos una hoja nueva por
        'cada consulta que se haya pasado
        'como parámetro
        Set hoja = appExcel.Sheets.Add
        nom = nombresQueries(i)

        'si el nombre de la consulta es
        '>31 caracteres dara error así que
        'lo recortamos
        If Len(nom) > 31 Then
            nom = Left(nom, 31)
        End If

        '... y le damos nombre a la hoja
        hoja.Name = nombresQueries(i)
        'abrimos la consulta
        Set rst = CurrentDb.OpenRecordset(nombresQueries(i))

        'ponemos nombre a las columnas de las hojas
        'igual que el nombre de los campos de la consulta
        fila = 1
        columna = 1
        For Each fld In rst.Fields
            hoja.Cells(fila, columna) = fld.Name
            columna = columna + 1
        Next

        'después traspasamos el valor de los campos
        'a las celdas de la hoja de excel
        fila = 2
        columna = 1
        While Not rst.EOF
            For Each fld In rst.Fields
                hoja.Cells(fila, columna) = fld.Value
                columna = columna + 1
            Next
            columna = 1
            fila = fila + 1
            rst.MoveNext
        Wend

        rst.Close

    Next

    Set appExcel = Nothing

End Sub