Gracias de antemano por la ayuda, quiero importar datos de una bd Access a
otra igual bajo las siguientes condiciones:

1.- Es necesario que la importacion se realize por medio de un programa en
VB 6
2.- Tengo dos bd access que son exactamente iguales (las mismas tablas con
la misma estructura)
3.- La conexion a las bd son por codigo y usando ADO.
4.- Las consultas a las tablas por ejemplo lo hago de la siguiente forma
     ''BD Access: Actual.Mdb.
     Set Rs1 = New ADODB.Recordset
     Rs1.Open "Select * From Tabla1 ", GConex.dataActual, adOpenKeyset
     Set MSHF1.DataSource = Rs1

     ''BD Access: Anterior.Mdb.
     Set Rs2 = New ADODB.Recordset
     Rs1.Open "Select * From Tabla1 ", GConex.dataAnterior, adOpenKeyset
     Set MSHF1.DataSource = Rs2

     ''Las consultas funcionan bien.
5.- Para actualizar datos en una tabla lo hago de la siguiente forma
     GConex.dataActual.Execute "Insert Tabla1 (Campo1, Campo2.....) Values
( Valor1, Valor2 ....)"

Responde Búho
=============
Esto, podría servirte:
Sub prueba()
Dim ObjCnn As ADODB.Connection
Dim RegistrosAfectados As Long
Set ObjCnn = New ADODB.Connection
'la base «baseorigen.mdb» es la origen de datos, es decir, de la que 
copiamos
With ObjCnn
    .Provider = "Microsoft.Jet.OLEDB.4.0"
    .ConnectionString = "Data Source = " & CurrentProject.Path & _
        "\baseorigen.mdb"
    .Open
    Dim Ruta As String
    'la base «basedestino.mdb» es la destinataria de los datos
    Ruta = CurrentProject.Path & "\basedestino.mdb"
    .Execute "INSERT INTO NombreTabla in '" & Ruta & _
        "' SELECT * FROM NombreTabla", RegistrosAfectados, adCmdText
End With

MsgBox "Registros copiados: " & RegistrosAfectados
End Sub

Por supuesto,para Visual, quita las palabras CurrentProject.Path  etc y mete 
las rutas reales de las MDB

---------------------------------------------------------------
Excelente, era la solución que necesitaba, muchas gracias. y si pudieras
ayudarme con esto mas por favor:

Como puedo hacer una consulta o programa para crearme un arreglo contiendo
todos los nombres de las tablas de un bd Access cualquiera.
----------------------------------------------------------------
Responde Buho
=============

Me alegro que te sriviera.
Esta es una de las multiples formas enque sacas las tablas de una MDB
Sub DameEstructuraSimple()

   Dim Conexion As ADODB.Connection
   Dim RstSchema As ADODB.Recordset

   Set Conexion = New ADODB.Connection
   Conexion.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
      "Data Source=" & APP.Path & "\Tumdb.mdb;"

   Set RstSchema = Conexion.OpenSchema(adSchemaTables)

   Do Until RstSchema.EOF
      Debug.Print "Nombre de la Tabla: " & _
         RstSchema!TABLE_NAME & vbCr & _
         "Tipo de tabla: " & RstSchema!TABLE_TYPE & vbCrLf
      RstSchema.MoveNext
   Loop
   RstSchema.Close

   Conexion.Close

End Sub