Tengo una pequeña aplicación, uno de cuyos campos es un 
campo memo con cantidad de información. Me han pedido que 
cuando realicen una búsqueda que no distinga los acentos, 
es decir, por ejemplo, en una búsqueda de registros que 
contengan la palabra "calefacción" debería sacar tanto los 
que tienen la o acentuada como los que no la tienen.

¿Hay alguna manera de conseguir esto?


RESPONDE EDUARDO OLAZ
=====================

Debes pasar tanto el campo del query como el parámetro a comparar por una
función que quite acentos.

Aquí te adjunto una que te podría servir:

Para que te distinga mayúsculas y minúsculas debes quitar la línea
        [Option Compare Database]
que aparece al principio del módulo en el que escribas la función

_______________________________________________

Public Function CadenaSinAcentos(ByVal Cadena As String) As String
    Dim strCaracter As String
    Dim i As Long
    For i = 1 To Len(Cadena)
        strCaracter = Mid(Cadena, i, 1)
        Select Case strCaracter
            Case "à", "á", "â", "ã", "ä", "å"
                strCaracter = "a"
            Case "è", "é", "ê", "ë"
                strCaracter = "e"
            Case "ì", "í", "î", "ï"
                strCaracter = "i"
            Case "ò", "ó", "ô", "õ", "ö"
                strCaracter = "o"
            Case "ù", "ú", "û", "ü"
                strCaracter = "u"
            Case "ý", "ÿ"
                strCaracter = "y"
            Case "À", "Á", "Â", "Ã", "Ä", "Å"
                strCaracter = "A"
            Case "È", "É", "Ê", "Ë"
                strCaracter = "E"
            Case "Ì", "Í", "Î", "Ï"
                strCaracter = "I"
            Case "Ò", "Ó", "Ô", "Õ", "Ö"
                strCaracter = "O"
            Case "Ù", "Ú", "Û", "Ü"
                strCaracter = "U"
            Case "Y", "Ý"
                strCaracter = "Y"
        End Select
        CadenaSinAcentos = CadenaSinAcentos & strCaracter
    Next i
End Function