Debo hacer un formulario para introducir los datos de las facturas que voy
haciendo.  Espero que entre todos podáis ayudarme a conseguirlo.
Mi primera duda es la siguiente:

El número de factura estará formado de la siguiente manera:
dos últimos dígitos del año, dos cifras del mes,guión,número consecutivo de
4 cifras.
Ejemplo:
* La factura número 1 que se hizo en el mes de enero del año actual sería:
0201-0001
* La factura número 52 que se hiciera en el mes de abril del año actual
sería: 0204-0052

¿qué código usar para que se enumeren automáticamente las facturas de este
modo?


EDUARDO OLAZ
============
Esto te servirá:

Suponiendo que tengas la tabla Facturas con el campo idFactura como
numerador:
A la función le pasas la fecha de la factura y te devuelve el nuevo
númerotras consultar las facturas existentes previamente en dicha tabla.
____________________________________

Public Function NuevoNumeroFactura( _
    ByVal Fecha As Date) _
    As String
    ' Genera números de factura del tipo
    ' AAMM-0000
    ' 24/10/02 Eduardo Olaz eduardo@olaz.net
    Const conCeros As String = "0000"
    Dim strNumero As String
    Dim lngNumero As Long
    strNumero = Format(Fecha, "yy") _
                & Format(Fecha, "mm") & "-"
    strNumero = Nz(DMax( _
        "idFactura", _
        "Facturas", _
        "idFactura like '" & strNumero & "*'"), _
        strNumero & conCeros)
    lngNumero = Val(Right(strNumero, Len(conCeros)))
    lngNumero = lngNumero + 1
    NuevoNumeroFactura = Left(strNumero, 5) _
            & Format(lngNumero, conCeros)
End Function
____________________________________