Necesito seleccionar el valor mas pequeño en un conjunto
de CAMPOS dentro de un mismo Registro

Encontre opciones para seleccionar el valor mas pequeño de
un campo en particular pero evaluando un conjunto de
registros

Espero que alguien tenga alguna idea



RESPONDE EDUARDO OLAZ
=====================

Aquí te paso las funciones Maximo(Array) y Minimo(Array) que te devolvería
el máximo o el mínimo valor de un array pasado como parámetro.
Puedes pasarle un array con los valores de los campos y te devolverá el
máximo o el mínimo valor entre los pasados.
Te adjunto dos ejemplos en los que se pasan valores long y string.
_____________________________________________

Public Function Maximo(Valores As Variant) As Variant
    Dim i As Long
    Dim lngInferior As Long
    Dim varMaximo As Variant

    lngInferior = LBound(Valores)
    varMaximo = Valores(lngInferior)
    For i = lngInferior + 1 To UBound(Valores)
        If Valores(i) > varMaximo Then
            varMaximo = Valores(i)
        End If
    Next i
    Maximo = varMaximo
End Function

Public Function Minimo(Valores As Variant) As Variant
    Dim i As Long
    Dim lngInferior As Long
    Dim varMinimo As Variant

    lngInferior = LBound(Valores)
    varMinimo = Valores(lngInferior)
    For i = lngInferior + 1 To UBound(Valores)
        If Valores(i) < varMinimo Then
            varMinimo = Valores(i)
        End If
    Next i
    Minimo = varMinimo
End Function


Public Function LongMaximo() As Long

    Dim aValores As Variant
    Dim Campo1 As Long
    Dim Campo2 As Long
    Dim Campo3 As Long
    Dim Campo4 As Long
    ' ***************************************
    ' Aquí se cargarían los valores de los campos desde el registro
    Campo1 = 1
    Campo2 = 10
    Campo3 = -2
    Campo4 = 5
    ' ***************************************
    aValores = Array(Campo1, Campo2, Campo3, Campo4)
    LongMaximo = Maximo(aValores)
End Function

Public Function StringMinimo() As String

    Dim aValores As Variant
    Dim Campo1 As String
    Dim Campo2 As String
    Dim Campo3 As String
    Dim Campo4 As String
    ' ***************************************
    ' Aquí se cargarían los valores de los campos desde el registro
    Campo1 = "López"
    Campo2 = "Martínez"
    Campo3 = "Gómez"
    Campo4 = "Olaz"
    ' ***************************************
    aValores = Array(Campo1, Campo2, Campo3, Campo4)
    StringMinimo = Minimo(aValores)
End Function
_____________________________________________