'*********************************************************
' BackUpBackEnd
'
' Esta rutina está diseñada para localizar la ruta de la
' base de datos que sirve como origen de datos (BackEnd),
' y hacer una copia de seguridad.
' 
' El método FileCopy de VBA sólo funciona en archivos
' cerrados, por eso utilizamos el método CopyFile de
' FSO.
'
' Argumentos
'    Destination: Ruta y nombre del archivo destino
'
Sub BackUpBackEnd(Destination As String) 
Dim tdf As TableDef
Dim strConnect As String
Dim pos As Integer
Dim fso As Object 'New FileSystemObject

    For Each tdf In CurrentDb.TableDefs
        If tdf.Connect <> "" Then
            pos = InStr(tdf.Connect, "=")
            strConnect = Right(tdf.Connect, _
                         Len(tdf.Connect) - pos)
            Exit For
        End If
    Next
    
    If strConnect <> "" Then
        Set fso = CreateObject( _
                  "Scripting.FileSystemObject")
        fso.CopyFile strConnect, Destination
        Set fso = Nothing
    End If
    
End Sub
'*********************************************************