'**********************************************************
' Función mostrarArchivosWSH
'
' Función que recorre recursivamente un directorio y lista
' todos sus archivos, subdirectorios y los archivos 
' contenidos dentro de ellos, mostrándolos en la barra de
' estado de Access. Utiliza el FSO (File System Object).
'
' La función Dir de VB no puede usarse en procedimientos
' recursivos y por tanto no se puede utilizar más que para
' conocer el contenido de un solo directorio.
'
' Argumentos
'   nomCarpeta: Nombre del directorio a partir del cual se
'   empezará a buscar.
'
' Autor: Juan M. Afán de Ribera
'
' Fecha: Septiembre 2003
'
Sub mostrarArchivosWSH(nomCarpeta)
Dim fso As Object 'New FileSystemObject
Dim carpeta As Object 'Folder
Dim subCarpeta As Object 'Folder
Dim archivos As Object 'Files
Dim archivo As Object 'File

    Set fso = CreateObject("Scripting.FileSystemObject")
    Set carpeta = fso.GetFolder(nomCarpeta)
    
    SysCmd acSysCmdSetStatus, carpeta.Name
    Set archivos = carpeta.Files
    For Each archivo In archivos
        SysCmd acSysCmdSetStatus, nomCarpeta _
        & "\" & archivo.Name
    Next
    Set archivos = Nothing
    
    ' utiliza este bucle para saber las subcarpetas
    ' y archivos contenidas en la carpeta actual
    For Each subCarpeta In carpeta.SubFolders
        mostrarArchivosWSH nomCarpeta _
        & "\" & subCarpeta.Name
    Next

    Set carpeta = Nothing
    Set fso = Nothing
    
    SysCmd acSysCmdClearStatus
    
End Sub
'*****************************************