'*********************************************************
' El siguiente ejemplo muestra en la ventana de inmediato
' las propiedades de las unidades existentes en el sistema
' actual.
' 
' Objetos utilizados:
'   
'   FileSystemObject
'   Drives (colección)
'   Drive
'
Sub DriveProperties()
Dim fso As Object 'New FileSystemObject
Dim drv As Object 'Drive

    Set fso = CreateObject("Scripting.FileSystemObject")
    
    For Each drv In fso.Drives
        On Error Resume Next
        
        Debug.Print "Letra unidad: " & drv.DriveLetter
                    
        Debug.Print "- Tipo de unidad: ";
        Select Case drv.DriveType
            Case 0: Debug.Print "Desconocido"
            Case 1: Debug.Print "Removible"
            Case 2: Debug.Print "Fija"
            Case 3: Debug.Print "Red"
            Case 4: Debug.Print "CD-ROM"
            Case 5: Debug.Print "Disco RAM"
        End Select
        
        Debug.Print "- Ruta: "; _
                    drv.Path
        Debug.Print "- Directorio raiz: "; _
                    drv.RootFolder
        Debug.Print "- Nombre volumen: "; _
                    drv.VolumeName
        Debug.Print "- Preparada: "; _
                    drv.IsReady
        Debug.Print "- Capacidad total: "; _
                    Format(drv.TotalSize, "##,###")
        Debug.Print "- Espacio libre: "; _
                    Format(drv.FreeSpace, "##,###")
        Debug.Print "- Sistema de archivos: "; _
                    drv.FileSystem
        Debug.Print "- Número de serie: "; _
                    drv.SerialNumber
        Debug.Print "- Nombre recurso compartido: "; _
                    drv.ShareName
    Next
       
    Set fso = Nothing
    
End Sub
'*********************************************************